[VBA] Boήθεια με τα σχόλια

[Dimitris Ch]

Καλησπερα σε ολο το Forum

Γραφω μια ρουτινα σε VBA με την οποια τοποθετω καποια σχολια (NoteText) σε καποια κελια
Δεν καταφερα ομως να βρω με ποιο τροπο μπορω να τα μορφοποιησω
Βασικα σε πρωτη πρωτη φαση θελω να αλλαξω το μεγεθος των γραμμάτων

Ευχαριστω εκ των προτερων και συγχαρητηρια για την δουλεια σας
Δημητρης

[mdragon]

Δημήτρη καλημέρα,
έχω χρησιμοποιήσει τυχαία κελιά......

Range("E5,G9,K9,J5,M5,M13,G15,A14,A6,C7").Select
Selection.Font.Bold = True


Καλή συνέχεια,
Μάρω

[Dimitris Ch]

Μαρω ευχαριστω κατ' αρχην για την απαντηση σου.
αυτο που μου γραφεις ομως αφορα το περιεχομενο του κελιου και οχι το σχολιο
Εγω θελω να κανω μορφοποιηση στο σχολιο που εχω σ ενα κελι και οχι στο περιεχομενο του

Ευχαριστω Δημητρης

[mdragon]

Έχεις δίκιο Δημήτρη,
διάβασα πολύ γρήγορα το μήνυμά σου και δεν κατάλαβα ότι εννοούσες το σχόλιο.
Θα το ψάξω και θα επανέλθω, εκτός αν με προλάβει κάποιος άλλος.....





Φιλικά,
Μάρω

[Tasos]

Καλησπέρα σε όλους!

Κοιτάξτε τον παρακάτω παραδειγματικό κώδικα:

Sub FormatMyComment()
    With ActiveCell
        If Not .Comment Is Nothing Then
            With .Comment.Shape.TextFrame.Characters.Font
                .Italic = True
                .Size = "10"
                .Name = "Arial"
                .ColorIndex = 0
            End With
            With .Comment.Shape.TextFrame
                .Characters.Text = "ms-Office.gr" & vbLf & "This is a test"
                With .Characters(1, Len("ms-Office.gr"))
                    .Font.ColorIndex = 3
                    .Font.Italic = False
                    .Font.Bold = True
                End With
            '.AutoSize = True
            End With
            With .Comment.Shape
                .Shadow.Transparency = 0.5
                .Fill.ForeColor.SchemeColor = 44
                .Fill.OneColorGradient msoGradientHorizontal, 4, 0.5
                .Fill.Transparency = 0.5
            End With
        End If
    End With
End Sub

Χρησιμοποιώντας τα σωστά αντικείμενα (όχι Selection κτλ. που καταγράφει ο Macro Recorder) θα έχουμε την πλήρη υποστήριξη του InteliSence στον VBE.

Καλή συνέχεια!

Φιλικά

Τάσος

[Dimitris Ch]

Aπλα τελειο
Τασο σ ευχαριστω πολυ......δεν εχω λογια

Φιλικα Δημητρης

[mdragon]

Μπράβο βρε Τάσο.
Την καλημέρα μου σε όλη την παρέα





Μάρω