[Συναρτήσεις] Ενεργή συμμετοχή ...

[Tasos]

Έχεις δίκιο! Έτσι την έχω κι εγώ αλλά απλά επικόλλησα λάθος συνάρτηση!
Δεν βγάζει όμως σε καμία περιπτωση #VALUE!.

[Θανάσης]

Καλησπέρα σας
να μπώ και εγώ σφήνα στους ειδικούς με μια συνάρτηση που με είχε ταλαιπωρήσει για καιρό και κατάφερα να βρώ μόνος μου.

Εύρεση τριμήνου από ημερομηνία

αν έχουμε μια ημερομηνία στο κελί Α1 πχ 8/2/2010 τότε ο τύπος:

=ROUND((MONTH(A1)+1)/3;0)&"ο τρίμηνο"

μας δίνει το τρίμηνο δηλαδή "1ο τρίμηνο" για το παράδειμα.

Θανάσης
ΥΓ. Μπράβο παιδιά πολύ χρήσιμο αυτό με τον ΑΦΜ

[nisgia]

Αρχική Δημοσίευση από Θανάσης

Καλησπέρα σας
να μπώ και εγώ σφήνα στους ειδικούς...

Καλησπέρα Θανάση!
Φυσικά να μπεις και εσύ! Χωράει πολλούς καλούς αυτό το φόρουμ!

Πολύ χρήσιμος ο τύπος σου και μάλιστα μπορούμε να αντικαταστήσουμε την ROUND() με την INT() όπως παρακάτω:
Φαντάζομαι θα είναι πιο γρήγορη από την ROUND...

=INT((MONTH(A1)-1)/3)+1

Φυσικά στο ίδιο μοτίβο λειτουργούμε και για εξάμηνα κτλ.

=INT((MONTH(Α1)-1)/6)+1

Φιλικά,
Γιάννης

[nisgia]

Τώρα με τις περικοπές και τα σκληρά μέτρα λιτότητας, πιθανώς να μας φανεί χρήσιμος
και ο παρακάτω τύπος ο οποίος επιστρέφει την πλησιέστερη τιμή σε μια τιμή στόχο από μια περιοχή τιμών μιας στήλης.
Έτσι, για να βρίσκουμε τα πιο κοντινά στις οικονομικές μας δυνατότητες προϊόντα.

=INDEX($A$1:$A$10;MATCH(MIN(INDEX(ABS($A$1:$A$10-C1);));INDEX(ABS($A$1:$A$10-C1););0))

Όπου $A$1:$A$10 η περιοχή αναζήτησης και C1 η τιμή στόχος.
Φυσικά η περιοχή αναζήτησης της εξωτερικής INDEX() μπορεί να είναι διαφορετική από τις άλλες δύο.

Δοκιμάστε τον.

Υ.Γ.
Κάτι μου λέει πως το θέμα θα μετονομαστεί σε: Αγαπάς το Excel; Απόδειξη!!!

[nisgia]

Όχι Τάσο! Το σωστό είναι έτσι: "MOD(MOD(Άθροισμα;11);10)"

=IF(A1<>"";IF(LEN(A1)=9;IF(MOD(MOD(SUM(MID(A1;9-ROW($1:$8);1)*2^ROW($1:$8));11);10)=RIGHT(A1;1)*1;"ΟΚ!";
"Άκυρο!");"Λάθος καταχώρηση!");"")

Μην ξεχνάτε, είναι τύπος πίνακα CSE. Εισάγεται με Ctrl+Shift+Enter.

Αν θέλεις τσεκάρισε τους Α.Φ.Μ. ΕΔΩ.
Για παράδειγμα ο "090000010" είναι έγκυρος ενώ ο "090000020" όχι.

Η τιμή #VALUE! βγαίνει όταν υπάρχει μη αριθμητικός χαρακτήρας μέσα στον Α.Φ.Μ.
Για παράδειγμα ένα κεφαλαίο όμικρον (Ο) αντί για μηδέν (0).
Μοιάζουνε κιόλας τα σκασμένα!

[gr8styl]

Δεν πρόκειται για συνάρτηση αλλά για ένα πολύ χρήσιμο κατά την γνώμη μου κόλπο.

Θα έχετε διαπιστώσει ίσως ότι όταν το κελί που θέλουμε να εφαρμόσουμε Επικύρωση δεν βρίσκεται στο ίδιο φύλλο με την λίστα που θέλουμε, το Excel (τουλάχιστον μέχρι την έκδοση 2003) δεν το δέχεται.
Η λύση βρίσκεται στο να ορίσουμε κάποιο όνομα για την επιθυμητή λίστα και να εισάγουμε το όνομα αντί της διεύθυνσης της περιοχής.

Παράδειγμα: Αν στο φύλλο1 η περιοχή a1 έως a5 έχει ονόματα φρούτων, και θέλουμε να μπορούμε να επιλέγουμε ένα από αυτά στο κελί a1 του φύλλο2, εργαζόμαστε ως εξής:
Στο Φύλλο1 επιλέγουμε την περιοχή από a1 έως a5 και στο μενού Εισαγωγή Όνομα Ορισμός γράφουμε frouta (η Αναφορά σε: δείχνει "=Φύλλο1!$A$1:$A$5").
Πάμε στο Φύλλο2 και επιλέγουμε το κελί a1 στο μενού Δεδομένα Επικύρωση επιλέγουμε Επιτρεπόμενη καταχώρηση "Λίστα" και στο Προέλευση γράφουμε =frouta

Ελπίζω να σας φανεί χρήσιμο.
Γενικότερα η χρήση ονομάτων στο Excel είναι κάτι σαν ορισμός μεταβλητών.
Θανάσης

ΥΓ. Στο Excel 2007 μπορούμε γράψουμε κατευθείαν =Φύλλο1!$a$1:$a$5 στο Προέλευση, αλλά δεν μπορούμε να επιλέξουμε με το ποντίκι την περιοχή.

[gr8styl]

Μερικές φορές όταν θέλουμε να συγκρίνουμε δύο κελιά μας ενδιαφέρει να δούμε αν έχουν το ίδιο ακριβώς περιεχόμενο. Δηλαδή να γίνεται διάκριση πεζών κεφαλαίων.

Παράδειγμα: το "Τιμή_1" είναι διαφορετικό από το "τιμή_1" ή το "ΤΙΜΗ_1"

Αν υποθέσω ότι τα δύο προς σύγκριση κελιά είναι το Α1 και το Β1 τότε η απάντηση είναι ο τύπος:

=IF(OR(ISERROR(FIND(A1;LEFT(B1;LEN(A1))));ISERROR(FIND(B1;LEFT(A1;LEN(B1)))));"Α1≠Β1";"Α1=Β1")

Συχνά μας διευκολύνει να προκύπτει ισότητα μεταξύ κεφαλαίων και πεζών χαρακτήρων όχι όμως πάντα.
Εσείς αποφασίζεται αν είναι χρήσιμο και πότε χρειάζεται η διαφοροποίηση.

Τώρα ξέρετε τον τρόπο

Θανάσης

[nisgia]

Θανάση, δεν κατάλαβα σωστά ή ο παρακάτω τύπος είναι ισοδύναμος με τον τύπο που μας έδωσες;

=IF(EXACT(A1;B1);"Α1=Β1";"Α1≠Β1")

[gr8styl]

Καλημέρα.

φίλε Γιάννη εσύ πολύ σωστά κατάλαβες. Τώρα όσο για μένα, εγώ έμαθα την ύπαρξη της EXACT που αγνοούσα μέχρι σήμερα !!!

Ευχαριστώ.

ΥΓ. Να που πάντα υπάρχει κατι που δεν ξέρουμε και μαθαίνουμε. Το να το θυμόμαστε βέβαια είναι άλλο κεφάλαιο.