Διόρθωση κώδικα σε Module

[alex]

Καλημέρα σε όλους τους φίλους του φορούμ
Μια βοήθεια σε κώδικα module
Εχω μια βάση και θέλω να βγάζει τα γενέθλια με την έκκίνηση της εφαρμογής σε μήνυμα.ναι η όχι να ανοίξει κάποια φόρμα.
Το έχω κάνει με άλλο τρόπο όπου και φαίνεται στην βάση που θα ανεβάσω.
Εχω όμως και ένα άλλο τρόπο και έχω τα εξής
1. module BasAutoExecBirthDay
2. TblParameter
3. TblCustomer
4. Η φόρμα Διαχείριση Εmails (Δεν υπάρχει ακόμη)
Μήπως γνωρίζει κανείς πώς θα συντάξω τον κώδικα στο module ώστε να βγάζει μήνυμα σήμερα εχουν τα γεννέθλια να ανοίξει η φόρμα Διαχείριση Εmails;
Ευχαριστώ εκ των προτέρων
Φιλικά/Αλέξανδρος

[kapetang]

Καλημέρα

Αλέξανδρε, άλλαξε τον κώδικα στο module BasAutoExecBirthDay με τον ακόλουθο:

Option Compare Database
Option Explicit

'Ρουτίνες που ενεργοποιούνται με την έναρξη της εφαρμογής
Public Sub sShowNameBirthDay()

    'Ρουτίνα που εμφανίζει τα γεννέθλια των πελατών
    Dim i As Integer, TmpName As String
    Dim RcdNames As New ADODB.Recordset
    Dim Response As Integer
    Const CnstNameTable As String = "[TblBirthDay query]"

    RcdNames.Open "Select * From " & CnstNameTable & ";", CurrentProject.Connection, adOpenDynamic

    If Not (RcdNames.EOF And RcdNames.BOF) Then
        RcdNames.MoveFirst
        Do While Not RcdNames.EOF
            i = i + 1
            If i > 1 Then
                TmpName = TmpName & vbCrLf & i & "." & RcdNames.Fields("LastName")
            Else
                TmpName = i & "." & RcdNames.Fields("Lastname")
            End If
            RcdNames.MoveNext
        Loop
        Response = MsgBox("Καλημέρα, σήμερα έχουν τα γεννέθλιά τους : " & vbCrLf & TmpName _
        & vbNewLine & "Να ανοίξει αυτόματα η διαχείριση των Emails", vbYesNo, "Διαχείριση Emails")
        'Εδώ είναι ο κώδικας για το άνοιγμα της φόρμας Emails
        'if responce=vbyes then docmd.OpenForm "frmEmails"
    End If
    RcdNames.Close
End Sub

Δεν ασχολήθηκα με τα TblParameter και TblCustomer, γιατί δε χρειάζονται.
Ένα MsgBox μπορεί να εμφανίσει περιορισμένο κείμενο, οπότε αν έχουν πολλοί γενέθλια, ενδέχεται να μη εμφανιστούν όλοι.

Φιλικά/Γιώργος

[alex]

Καλημέρα Γιώργο

Ευχαριστώ πολύ για την βοήθεια.Πιστεύω με αυτο τον τρόπο η βάση είναι πιο ευέληκτη και γρήγορη απο ότι πρίν με ερωτήματα.
Ευχαριστώ και καλό μεσημέρι

Φιλικά/Αλέξανδρος