[Συναρτήσεις] Index & Match

[dealer_xm]

Καλησπέρα σας,

Σε ένα αρχείο χρησιμοποιώ μια συνάρτηση με IFERROR, INDEX & MATCH ώστε όταν εισάγω ένα κωδικό προϊόντος να μου εμφανίζει την περιγραφή του συγκεκριμένου προϊόντος.

Υπάρχει τρόπος να συνεχίσει να λειτουργεί αυτή η συνάρτηση αν στα προϊόντα προστεθεί ακόμα μια στήλη με δεύτερο κωδικό? Δηλαδή κάθε προϊόν να αποτελείται απο τον κύριο κωδικό και τον εναλλακτικό κωδικό και εισάγωντας τον έναν ή τον άλλο να εμφανίζεται η περιγραφή του προϊόντος.

Ευχαριστώ.

[ChrisGT7]

Καλησπέρα Χρήστο,

Δοκίμασε την παρακάτω συνάρτηση αν σου κάνει:
=IFERROR(INDEX(C:C;MATCH(E1;A:A;0));"")&IFERROR(INDEX(C:C;MATCH(E1;B:B;0));"")

όπου:
C:C = η στήλη που περιέχει τις περιγραφές ειδών
Ε1 = το κελί που πληκτρολογείς τον κωδικό είδους (κύριο ή εναλλακτικό)
Α:Α = η στήλη που περιέχει τους κύριους κωδικούς
Β:Β = η στήλη που περιέχει τους εναλλακτικούς κωδικούς

Τροποποιείς τα παραπάνω εύρη και κελιά σύμφωνα με τις ανάγκες σου.

[dealer_xm]

Καλησπέρα Χρήστο,

Η συνάρτηση δουλεύει υπέροχα.
Σ`ευχαριστώ πολύ.

Καλό βράδυ.

[dealer_xm]

Καλησπέρα σας,

Επαναφέρω το θέμα καθώς χρειάζομαι μια βοήθεια.

Χρησιμοποιώ τους παραπάνω τύπους μαζί στο ίδιο κελί σε ένα αρχείο με προϊόντα, γιατί τα προϊόντα αποτελούνται απο 2 κωδικούς (τον κύριο και τον εναλλακτικό), ώστε εάν κάποιος εισάγει κάποιον απο τους 2 κωδικούς να του εμφανιστεί η περιγραφή του προϊόντος.

Το ερώτημα είναι πως θα μπορούσαν να συνδυαστούν αυτοί οι 2 τύποι (ίσως με κάποια IF ή κάποια άλλη συνάρτηση), ώστε αν κάποιος εισάγει λάθος κωδικό, να εμφανίζεται στο κελί η ένδειξη "ΛΑΘΟΣ ΚΩΔΙΚΟΣ".

=IFERROR(INDEX(C:C;MATCH(E1;A:A;0));"ΛΑΘΟΣ ΚΩΔΙΚΟΣ")&IFERROR(INDEX(C:C;MATCH(E1;B:B;0));"ΛΑΘΟΣ ΚΩΔΙΚΟΣ")

Σας ευχαριστώ.

[kapetang]

Καλησπέρα

Δοκίμασε τον τύπο:

=IF(IFERROR(INDEX(C:C;MATCH(E1;A:A;0));"")&IFERROR (INDEX(C:C;MATCH(E1;B:B;0));"")="";"ΛΑΘΟΣ ΚΩΔΙΚΟΣ";IFERROR(INDEX(C:C;MATCH(E1;A:A;0)) ;"")&IFERROR(INDEX(C:C;MATCH(E1;B:B;0));""))

και λίγο συντομότερος:

=IF(IFERROR(MATCH(E1;A:A;0);"")&IFERROR(MATCH(E1;B :B;0);"")="";"ΛΑΘΟΣ ΚΩΔΙΚΟΣ";IFERROR(INDEX(C:C;MATCH(E1;A:A;0)) ;"")&IFERROR(INDEX(C:C;MATCH(E1;B:B;0));""))

Μάλλον ο καλύτερος:

=IF(ISERROR(MATCH(E1;A:A;0));IF(ISERROR(MATCH(E1;B :B;0));"ΛΑΘΟΣ ΚΩΔΙΚΟΣ";INDEX(C:C;MATCH(E1;B:B;0)));INDEX( C:C;MATCH(E1;A:A;0)))

και ο καλύτερος:

=IFERROR(INDEX(C:C;MATCH(E1;A:A;0));IFERROR(INDEX( C:C;MATCH(E1;B:B;0));"ΛΑΘΟΣ ΚΩΔΙΚΟΣ"))

[dealer_xm]

Σ`ευχαριστώ πολύ για την άμεση απάντηση και την βοήθεια που μας παρέχεις.

[kapetang]

Να είσαι καλά Χρήστο και καλή συνέχεια.

Πιστεύω να χρησιμοποιήσεις τον τελευταίο τύπο, που είναι συντομότερος, αλλά και ταχύτερος.

[dealer_xm]

Καλησπέρα Γιώργο,

Ναι, εννοείται πως την τελευταία θα χρησιμοποιήσω.
Απλώς την έβαλα μέσα σε μια IF ώστε όταν στο κελί δεν υπάρχει καταχωρημένος κωδικός, τότε να εμφανίζεται κενό και να μην γράφει ΛΑΘΟΣ ΚΩΔΙΚΟΣ. Ελπίζω να μη επιβαρύνεται ιδιαίτερα.

=IF(E1="";"";IFERROR(INDEX(C:C;MATCH(E1;A:A;0));IF ERROR(INDEX(C:C;MATCH(E1;B:B;0));"ΛΑΘΟΣ ΚΩΔΙΚΟΣ")))

[kapetang]

Καλησπέρεα Χρήστο.

Μια χαρά το αντιμετώπισες.