Ανανέωση ιστοσελίδας

[Billy]

Καλημέρα σας και συγχαρητήρια για την καλή δουλειά!

Η ερώτηση μου είναι:
Πως μπορώ χωρίς χρήση VBA να εμφανίσω όλα τα ονόματα των φύλλων ενός
βιβλίου Excel σε μια περιοχή ενός φύλλου;

Θέλω βάσει αυτών των ονομάτων (που είναι πολλά και αλλάζουν τακτικά) να δημιουργήσω
τύπους που θα μου επιστρέψουν αποτελέσματα από τα φύλλα αυτά.

Ελπίζω να έγινα κατανοητός.

Ευχαριστώ

Βασίλης

[nisgia]

Γεια χαρά Βασίλη!

Ο παρακάτω τύπος επιστρέφει το όνομα του Φύλλου1:

=MID(CELL("filename";Φύλλο1!A1);FIND("]";CELL("filename";Φύλλο1!A1))+1;255)

Φτιάχνοντας λοιπόν έναν τέτοιο τύπο για κάθε υπάρχον φύλλο του βιβλίου σου
θα έχεις μια λίστα με τα ονόματα των φύλλων η οποία θα ενημερώνεται αυτόματα
με κάθε μετονομασία τους, όχι όμως και με τη διαγραφή τους ή/και την εισαγωγή νέων.

Για να έχεις μια πλήρως ενημερώσιμη λίστα, θα πρέπει αναγκαστικά να καταφύγεις στη VBA.

Φιλικά,
Γιάννης

[Tasos]

Γεια σας!
Μπορούμε να χρησιμοποιήσουμε την (πολύ παλιά) συνάρτηση GET.WORKBOOK() που μας επιστρέφει τα ονόματα των φύλλων σε πίνακα (Array).

Ορίζουμε λοιπόν ένα νέο όνομα πχ. SheetNames (Στην Excel 2007 - στην καρτέλλα Τύποι > Ορισμός ονόματος), όπου στο πεδίο "Αναφορά σε" περνάμε τη συνάρτηση:

=GET.WORKBOOK(1+0*NOW())

Το +0*NOW() προκαλεί επανυπολογισμό του φύλλου (αναγκαιο αφού οι συναρτήσεις τέτοιου είδους δεν συμπεριλαμβάνονται όπως θα έπρεπε στο σοφό κατά τ άλλα σύστημα υπολογισμού της Excel).

Κατόπιν, σε κάποιο κελί χρησιμοποιούμε τον τύπο:

=IFERROR(MID(INDEX(SheetNames;ROWS($1:1));FIND("]";INDEX(SheetNames;ROWS($1:1)))+1;31);"")

και συμπληρώνουμε τη στήλη προς τα κάτω όσο χρειαστεί.

Γενικά, η χρήση της VBA αποτελεί μια πιο προσιτή μέθοδο αφού υποστηρίζεται επίσημα (τώρα και στο εγγύς μέλλον τουλάχιστον) από τη Microsoft και είναι κατά πολύ και πληρέστερη.

Τέλος, προσπάθησε όπως ανέφερε και ο Γιάννης να εισέλθεις στο κεφάλαιο VBA μιας και οι γνώσεις σου στην Excel είναι καλές.


Φιλικά

Τάσος

[Billy]

Καλημέρα.

Σας ευχαριστώ πολύ για τις απαντήσεις σας!

Και οι δύο λύσεις λειτουργούν σωστά.

Θα πρέπει να μελετήσω την VBA αλλά πρώτα θα πρέπει να βρω το χρόνο...

Με εκτίμηση

Βασίλης