[Excel07] Βοήθεια με αναζήτηση

[Tasos]

Καλημέρα!

Για να πληκτρολογείς ή να συμπληρώνεις αυτόματα στις στήλες Β9:Ε143 δηλαδή να μην χρησιμοποιείς τύπους:

1. Διέγραψε τους τύπους που περιέχουν
2. Φρόντισε να τα κελιά αυτά να μην είναι προστατευμένα
3. Αντικατέστησε όλο τον κώδικα της εντολής Private Sub InsertListRow() με τον παρακάτω:

Private Sub InsertListRow()
    Dim c As Range
    If Me.ListBox1.ListCount = 0 Then Exit Sub
    If Me.ListBox1.ListIndex = -1 Then Exit Sub
    Set c = Range("OrderCodes").Find(Me.ListBox1.Value, LookIn:=xlValues)
    If Not c Is Nothing Then GoTo ExitHere
    With Cells(Rows.Count, Range("OrderCodes").Column).End(xlUp).Offset(1)
        .Value = Me.ListBox1.Value
        .Offset(, 1).Value = ShData.Cells(Me.ListBox1.ListIndex + 2, 4).Value
        .Offset(, 2).Value = ShData.Cells(Me.ListBox1.ListIndex + 2, 5).Value
        .Offset(, 3).Value = ShData.Cells(Me.ListBox1.ListIndex + 2, 6).Value
        .Offset(, 4).Value = ShData.Cells(Me.ListBox1.ListIndex + 2, 7).Value
        Cells(.Row, 8).Select
        If Me.ChckFocusAfterNewEntry Then
            AppActivate Application.Caption
        End If
    End With
ExitHere:
    With Me.ListBox1
        If .List(.ListIndex, 2) = ItmIsMissing Then
            .List(.ListIndex, 2) = ItmExists
        End If
    End With
    If Not c Is Nothing Then
        Cells(c.Row, 8).Select
    End If
End Sub

Επίσης θα χρειαστεί να αντικαταστήσεις την εντολή Private Sub cmdClearAll_Click() με τον παρακάτω κώδικα:

Private Sub cmdClearAll_Click()
    Range("OrderCodes").Resize(Range("OrderCodes").Count, 7).ClearContents
    TextBox1_Change
    Me.Height = 223
    Me.ListBox1.Enabled = True
    Me.TextBox1.Enabled = True
    Me.cmdClear.Enabled = True
    Me.cmdClearOrderList.Enabled = True
    Me.ChckFocusAfterNewEntry.Enabled = True
    Me.TextBox1.SetFocus
End Sub

Καλή συνέχεια!

Τάσος