ms-office.gr > Forum > Microsoft Excel > Excel - Ερωτήσεις / Απαντήσεις > [Γενικά] Πρόσθεση ηχητικού μηνύματος

Excel - Ερωτήσεις / Απαντήσεις Ότι έχει σχέση με συναρτήσεις, μορφοποίηση, εκτυπώσεις γραφήματα κτλ.

Απάντηση στο θέμα

 

Εργαλεία Θεμάτων Τρόποι εμφάνισης
  #1  
Παλιά 10-10-13, 12:17
Όνομα: Γιώργος
Έκδοση λογισμικού Office: Ms-Office 2007
Γλώσσα λογισμικού Office: Ελληνική
 
Εγγραφή: 08-02-2010
Μηνύματα: 31
Προεπιλογή Πρόσθεση ηχητικού μηνύματος

Καλημέρα στους φίλους και φίλες,

Έχω φτιάξει ένα αρχειάκι με τις τέσσερες πράξεις της απλής αριθμητικής για την εγγονή μου, το οποίο ανάλογα με την απάντηση που δίνει της εμφανίζει «ΣΩΣΤΟ» ή «ΛΑΘΟΣ».
Μέχρι εδώ όλα καλά ο προβληματισμός μου είναι αν μετά από κάθε απάντηση μπορεί να προστεθεί ένα ηχητικό επιβράβευσης αν η απάντηση είναι σωστή ή «αποδοκιμασίας» αν είναι λάθος.

Ευχαριστώ για τον χρόνο σας,

Γιώργος
Συνημμένα Αρχεία
Τύπος Αρχείου: xlsx ΑΡΙΘΜΗΤΙΚΗ ΚΩΝΣΤΑΝΤΙΝΑΣ_01.xlsx (46,0 KB, 53 εμφανίσεις)
Απάντηση με παράθεση
  #2  
Παλιά 10-10-13, 12:21
Όνομα: Γιώργος
Έκδοση λογισμικού Office: Ms-Office 2007
Γλώσσα λογισμικού Office: Ελληνική
 
Εγγραφή: 08-02-2010
Μηνύματα: 31
Προεπιλογή

Το παραπάνω αρχείο είναι σε είναι σε excel 2007 αλλά μόλις τώρα πληροφορήθηκα ότι στον υπολογιστή της έχει excel 2003 …

Ευχαριστώ και πάλι για τον χρόνο σας,

Γιώργος
Απάντηση με παράθεση
  #3  
Παλιά 10-10-13, 16:27
Το avatar του χρήστη Tasos
Διαχειριστής
Όνομα: Τάσος Φιλοξενιδης
Έκδοση λογισμικού Office: Ms-Office 365
Γλώσσα λογισμικού Office: Ελληνική, Αγγλική, Γερμανική
 
Εγγραφή: 21-10-2009
Μηνύματα: 2.249
Προεπιλογή

Καλησπέρα Γιώργο!

Δοκίμασε τον παρακάτω κώδικα στην κλάση "ThisWorkbook" του παραδείγματος που ανέβασες:


Κώδικας:
Option Explicit
Private Const SND_ASYNC = 1&
Private Declare Function PlaySound Lib "winmm.dll" _
                                   Alias "sndPlaySoundA" ( _
                                   ByVal lpszSoundName As String, _
                                   ByVal uFlags As Long) As Long

Private Sub PlaySoundFile(SoundPath As String)
    If Dir(SoundPath, vbNormal) <> "" Then
        PlaySound SoundPath, SND_ASYNC
    End If
End Sub

Private Function CheckValidity(rng As Range) As Boolean
    Dim ret As Double, i As Integer, EvalString As String
    If WorksheetFunction.CountA(rng) = rng.Count Then
        For i = 1 To rng.Count - 2
            If Trim(rng(i).Value) <> vbNullString Then
                EvalString = EvalString & Trim(Replace(rng(i).Value, "'", vbNullString))
            Else
               'PlaySoundFile "C:\Ο Φάκελος σου\Λάθος.wav
                PlaySoundFile Environ("SystemRoot") & "\Media\" & "chord.wav"
                MsgBox "Αφαίρεσε τα διαστήματα από το κελί " & rng(i).Address(False, False), vbInformation
                Exit Function
            End If
        Next
        ret = Evaluate(EvalString)
        If rng(i + 1).Value = ret Then
            'PlaySoundFile "C:\Ο Φάκελος σου\Σωστό.wav"
            PlaySoundFile Environ("SystemRoot") & "\Media\" & "tada.wav"
        Else
            'PlaySoundFile "C:\Ο Φάκελος σου\Λάθος.wav"
            PlaySoundFile Environ("SystemRoot") & "\Media\" & "chord.wav"
        End If
    End If
End Function

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    Select Case Sh.CodeName
        Case "Sheet1", "Sheet2", "Sheet3", "Sheet4", "Sheet5", "Sheet6"
            If Target.Row < 3 Then Exit Sub
            If Not Intersect(Target, Range("A:E")) Is Nothing Then
                CheckValidity Range(Cells(Target.Row, Range("A:E").Column), _
                                    Cells(Target.Row, Range("A:E").Column + _
                                                      Range("A:E").Columns.Count - 1))
            ElseIf Not Intersect(Target, Range("H:L")) Is Nothing Then
                CheckValidity Range(Cells(Target.Row, Range("H:L").Column), _
                                    Cells(Target.Row, Range("H:L").Column + _
                                                      Range("H:L").Columns.Count - 1))
            End If
    End Select
End Sub
Καλή συνέχεια!

ΥΓ. Ελπίζω να υπάρχουν αρκετοί παππούδες σαν εσένα στην Ελλάδα μας μπας και δούμε τουλάχιστον από τις νεότερες γενεές μια άσπρη μέρα!
__________________
Ms-Office Development Team
Ανάπτυξη επαγγελματικών εφαρμογών
Απάντηση με παράθεση
  #4  
Παλιά 10-10-13, 20:33
Όνομα: Γιώργος
Έκδοση λογισμικού Office: Ms-Office 2007
Γλώσσα λογισμικού Office: Ελληνική
 
Εγγραφή: 08-02-2010
Μηνύματα: 31
Προεπιλογή

Τάσο σε ευχαριστώ, θα το δοκιμάσω και τα λέμε.
Απάντηση με παράθεση
Απάντηση στο θέμα

Εργαλεία Θεμάτων
Τρόποι εμφάνισης

Δικαιώματα - Επιλογές
Δε μπορείτε να δημοσιεύσετε νέα μηνύματα
Δε μπορείτε να δημοσιεύσετε απαντήσεις
Δεν μπορείτε να επισυνάψετε αρχεία
Δεν μπορείτε να επεξεργαστείτε τα μηνύματα σας

Ο κώδικας ΒΒ είναι σε λειτουργία
Τα Smilies είναι σε λειτουργία
Ο κώδικας [IMG] είναι σε λειτουργία
Ο κώδικας HTML είναι εκτός λειτουργίας
Trackbacks are εκτός λειτουργίας
Pingbacks are εκτός λειτουργίας
Refbacks are εκτός λειτουργίας


Παρόμοια Θέματα

Θέμα Δημιουργός Forum Απαντήσεις Τελευταίο Μήνυμα
[ Πίνακες ] προσάρτηση συνημμένων μηνύματος σε πίνακα mousatos Access - Ερωτήσεις / Απαντήσεις 0 08-02-16 11:02
Επιλογή e-mail για αποστολή μηνύματος aristos Outlook - Ερωτήσεις / Απαντήσεις 1 06-06-13 00:04
Παράλειψη μηνύματος στο Word Dentos Word - Ερωτήσεις / Απαντήσεις 4 09-10-10 20:29
Έλεγχος textbox και εμφάνιση μηνύματος pm4698 Access - Ερωτήσεις / Απαντήσεις 2 11-03-10 12:41
[ Φόρμες ] Αντικατάσταση ...μηνύματος της Access Meteora Access - Ερωτήσεις / Απαντήσεις 2 10-02-10 20:32


Η ώρα είναι 09:01.