Κλείσιμο παραθύρου μηνύματος

[jorgis]

Καλησπέρα σε όλους.
Παρακαλώ, πως μπορεί να κλείνει το μήνυμα μετά απο 2'' Επισυνάπτω παράδειγμα:
Sub KillerXML()
Kill "C:\XML\ERROR\1.xml"
MsgBox "XML καταστράφηκε", vbInformation

End Sub

καλή συνέχεια στην δημιουργική παρέα.
Ευχαριστώ

[Tasos]

Καλησπέρα σε όλους!

Γιώργο βάλε τον παρακάτω κώδικα σε μια λειτουργική μονάδα και δοκίμασε τρέχοντας την "TestMessagBox".

Option Explicit

Sub TestMessagBox()
    MessageBox "XML καταστράφηκε.", 2, "Τίτλος"
End Sub

Sub MessageBox(Prompt As String, _
     Optional TimeSpan As Integer = 0, _
     Optional Title As String = "")

    Dim ScriptFilename As String
    Dim strText As String
    Dim fso    As Object
    Dim oStream As Object

    Set fso = CreateObject("Scripting.FileSystemObject")
    
    ScriptFilename = fso.BuildPath(Environ("TEMP"), "msg.vbs")
    
    strText = "CreateObject(""wscript.shell"").popup "
    
    strText = strText & Chr(34) & Prompt & Chr(34) & ", " & TimeSpan & ", " _
            & Chr(34) & Title & Chr(34) & ", 4160"
    
    Set oStream = fso.CreateTextFile(ScriptFilename, True, True)
    oStream.Write strText
    oStream.Close
    Set fso = Nothing
    Shell "wscript.exe " & Chr(34) & ScriptFilename & Chr(34)
End Sub

Καλή συνέχεια.

Με εκτίμηση

Τάσος

[jorgis]

ευχαριστώ πάρα πολύ. Καλή συνέχεια