[ Εκθέσεις ] Εξαγωγή αρχείου σε μορφή pdf και σε θέση της επιλογής μου

[ΤΙΜΟΣ]

Καλησπέρα σ' όλους,
Για άλλη μία φορά θα χρειαστώ βοήθεια από τα μέλη του φόρουμ. Με τον κώδικα που παραθέτω κάνω εξαγωγή συγκεκριμένης έκθεσης σε μορφή pdf σε καθορισμένη θέση , με προκαθορισμένο όνομα και δουλεύει άψογα. Το πρόβλημά μου είναι πως θέλω πριν την δημιουργία του pdf να έχω την δυνατότητα να επιλέξω σε ποιον φάκελο θα το αποθηκεύσω - κάτι σαν το SaveAs όπου η αποθήκευση γίνεται σε φάκελο της επιλογής μας.
Ο κώδικας :
Private Sub Εντολή482_Click()
DoCmd.OutputTo acOutputReport, "RptΔελτία παραγγελίας", acFormatPDF, "C:\Users\Timos\Εγγραφα PDF\" & "ΔΠ." & _
CStr(ΚωδΔελτίουπαραγγελίας) & "_κ.κ.." & CStr(Κείμενο218) & "_" & Format((Κείμενο194), "yyyymmdd") & ".pdf", True
End Sub

Ευχαριστώ εκ των προτέρων
Τίμος

[kapetang]

Καλημέρα
Τίμο, δοκίμασε τον κώδικα:

Public Function PicFolder() As String
    Dim blnSelect As Boolean
    Dim fld As Object

    Set fld = Application.FileDialog(4)
    fld.AllowMultiSelect = False
    blnSelect = fld.Show
    If blnSelect Then
        PicFolder = fld.SelectedItems(1)
    End If
End Function

Private Sub Εντολή482_Click()
    Dim strFolder As String
    strFolder = PicFolder
    If strFolder <> "" Then
        DoCmd.OutputTo acOutputReport, "RptΔελτία παραγγελίας", acFormatPDF, strFolder & "\ΔΠ." & _
            CStr(ΚωδΔελτίουπαραγγελίας) & "_κ.κ.." & CStr(Κείμενο218) & "_" & Format((Κείμενο194), "yyyymmdd") & ".pdf", True
    Else
        MsgBox "Δεν επιλέξατε φάκελο"
    End If
End Sub

Φιλικά/Γιώργος

[ΤΙΜΟΣ]

Καλησπέρα σε όλους,
Άψογος Γιώργο, δουλεύει τέλεια.
Ευχαριστώ για άλλη μία φορά , όπως και για την άμεση ανταπόκριση.