Ψάξιμο σε συγκεκριμένο πεδίο και εγραφή (vba)

[γιώργοςΚ]

Καλησπέρα σε όλους,

Στην βάση που φτιάχνω έχω τον πάρα κάτω κώδικα vba και για άλλη μια φορά χρειάζομαι την βοήθεια σας.

Private Sub cmdRegister_Click()

'Check value of Registration code in tblDbaseInfo to see if this matches value chosen in combo box

If Me.txtActKey.Value = DLookup("dbaseRegCode", "tblDbaseInfo") Then

lngMyRegKey = Me.txtActKey.Value

Me.txtPassword.Enabled = False
Me.Title2.Caption = "Verification key is correct.!!"

Me.activation = True
Me.trial = False
Me.ExpRegistration = Me.InstDate + 32
Me.ExpRegistration.Requery
Me.RegDays = 32
Me.RegDays.Requery

Forms!ftblLogin.Activated = True
Forms!ftblLogin.TrialMode = False


DoCmd.Close acForm, Me.Name
DoCmd.OpenForm "frmLogon"

Else

Me.txtActKey.SetFocus
End IF

End Sub

Θα ήθελα λοιπόν να όταν τρέχει ο πάρα πάνω κώδικας να "ψάχνει" στον πιο πάνω πίνακα αλλά πχ στην δεύτερη εγραφή του "dbaseRegCode" . Δεν γνωρίζω πώς μπορώ να επιτύχω κάτι τέτοιο και θα εκτιμούσα άν μπορεί κάποιος φίλος να βοηθήσει.

Σας ευχαριστώ εκ προτέρων

[kapetang]

Καλησπέρα

Γιώργο, μπορείς να χρησιμοποιήσεις την παρακάτω συνάρτηση:

Public Function ExistValue(numRecord As Long, valValue) As Boolean
'numRecord ο α/α της εγγραφής στην οποία θα γίνει η αναζήτηση
'valValue η τιμή την οποία αναζητούμε

    Dim rs As DAO.Recordset
    Set rs = CurrentDb.OpenRecordset("Select * FROM tblDbaseInfo")
    If Not (rs.EOF And rs.BOF) Then
        rs.MoveFirst
        rs.Move numRecord - 1
        If Not (rs.EOF Or rs.BOF) Then
            If rs!dbaseRegCode = valValue Then ExistValue = True
        End If
    End If
End Function

Η συνάρτηση επιστρέφει την τιμή True, αν η αναζητούμενη τιμή (παράμετρος valValue) ισούται με την τιμή του πεδίου dbaseRegCode της εγγραφής με συγκεκριμένο αύξοντα αριθμό (ορίζεται από την παράμετρο numRecord ) και False διαφορετικά

Φιλικά/Γιώργος

[γιώργοςΚ]

Γιώργο σε ευχαριστώ και πάλι για την βοήθεια.
Θα δοκιμάσω τον κώδικα που μου έδωσες προσαρμόζοντας τον φυσικά στα μέτρα μου και εάν και εφόσον αντιμετωπίσω καποιο θέμα θα επανέλθω.

Σε κάθε περίπτωση σε υπέρ-ευχαριστώ..

Υ.Γ: άτομα σαν και εσένα φίλε στον φόρουμ απλά το κάνουν και πιο πλούσιο αλλά και πιο βοηθητικό... Νάσαι καλά