Ένωση πολλών αρχείων Word σε ένα με χρήση Access

[dimmag]

Καλησπέρα σε όλα τα μέλη,

Προσπαθώ να δημιουργήσω μια βάση δεδομένων για την διαχείρηση πρακτικών ΔΣ.
Σε κάθε πράξη ΔΣ υπάρχουν 10, 20, 50 ή 100 θέματα. Για κάθε θέμα δημιουργώ ένα αρχείο Word με κωδικοποιημένη ονομασία παραδειγμα 2014_3_11.doc
Ετος 2014
Πράξη 3
Θέμα 11
Και στο Folder 2014_3 όλα τα θεματα με όνομα 2014_3…...doc δηλαδή της 3ης Πράξης
Κάθε αρχείο ανοίγει, μετακινήται ή μετονομάζεται από την βάση με κώδικα και fso

Αντιμετωπίζω ένα πρόβλημα που δυστυχώς δεν μπόρεσα να βρώ λύση ακόμη.

Δεν κατάφερα να βρώ τον κώδικα ώστε τα αρχεία πχ C:\000\test_1.doc, C:\000\test_2.doc, C:\000\test_3.doc,… να εισάγωνται στη σειρά σε ένα νέο αρχείο πχ C:\000\test.doc με τη σειρά που θέλω μέσα από την access πατώντας ένα κουμπί.
Δοκίμασα με τον παρακάτω κώδικα

Private Sub cmdCreatePraktiko_Click()
Dim wrdApp As Object
Dim wrdDoc As Object
Dim i As Integer
Set wrdApp = CreateObject("Word.Application")
wrdApp.Visible = True
Set wrdDoc = wrdApp.Documents.Add
With wrdDoc
For i = 1 To 3
.Content.InsertFile Filename:="C:\000\test_" & i & ".doc"
Next i
If Dir("C:\000\test.doc") <> "" Then
Kill "C:\000\test.doc"
End If
.SaveAs ("C:\000\test.doc")
.Close
End With
wrdApp.Quit
Set wrdDoc = Nothing
Set wrdApp = Nothing
End Sub

Δουλέυει αλλά κάθε φορά έχει μόνο το τελευταίο αρχείο. Δοκίμασα και

Set wrdDoc = wrdApp.Documents.Add (Template:= "C:\000\test_" & i & ".doc", NewTemplate:=False, DocumentType:=0)

Τα ίδια
Δεν ξέρω τη σωστή εντολή ή τη σύνταξη για να εισάγω σωστά τα αρχεία

Αν μπορεί ας βοηθήσει κάποιος

Ευχαριστώ εκ των προτέρων.

Φιλικά, Δημήτρης

[Tasos]

Καλησπέρα σε όλους!
Δημήτρη δοκίμασε:

Private Sub cmdCreatePraktiko_Click()
    Dim wrdApp As Object
    Dim wrdDoc As Object
    Dim wrdRange As Object
    Dim i As Integer
    Set wrdApp = CreateObject("Word.Application")
    wrdApp.Visible = True
    Set wrdDoc = wrdApp.Documents.Add
    With wrdDoc
        For i = 1 To 3
            Set wrdRange = .Range
            wrdRange.SetRange .Range.End, .Range.End
            wrdRange.InsertFile FileName:="C:\000\test_" & i & ".doc"
        Next i
        If Dir("C:\000\test.doc") <> "" Then
            Kill "C:\000\test.doc"
        End If
        .SaveAs ("C:\000\test.doc")
        .Close
    End With
    wrdApp.Quit
    Set wrdDoc = Nothing
    Set wrdApp = Nothing
End Sub

Με εκτίμηση

Τάσος

[dimmag]

Καλησπέρα σε όλους!

Τάσο σε ευχαριστώ πολύ, αυτό ήθελα

Δουλεύει άψογα

Με εκτίμηση

Δημήτρης