Λάθος σε κώδικα

[ΤΖΙΜΗΣ]

Καλημέρα σε όλη τη καλή παρέα.
Στο αρχείο που επισυνάπτω στη φόρμα ΕΓΓΡΑΦΕΣ και στο συμβάν με το κλικ στο μπουτόν Σύνολο ανά επωνυμία εμφανίζεται το μνμ "πολύ λίγες παράμετροι Αναμενόταν 1"
Τον κώδικα αυτό τον προσάρμοσα από μια παρόμοια πρόταση του Γιώργου (kapetang).
Μήπως κάποιος από την παρέα, μπορεί να μας πεις που βρίσκεται το λάθος;
Φιλικά Τζίμης.

[Tasos]

Καλημέρα Τζίμη!

Εγώ στη θέση του κουμπιού θα χρησιμοποιούσα ένα υπολογισμένο πεδίο
με τον παρακάτω τύπο στην προέλευση στοιχείου ελέγχου:

=IIf(Nz(DSum("[ΤΕΛΙΚΗ ΑΞΙΑ]";"[ΕΓΓΡΑΦΕΣ]";"[ΕΠΩΝΥΜΙΕΣ] = '" & [ΕΠΩΝΥΜΙΕΣ] & "'"))=0;"Δεν έγιναν πωλήσεις";DSum("[ΤΕΛΙΚΗ ΑΞΙΑ]"
;"[ΕΓΓΡΑΦΕΣ]";"[ΕΠΩΝΥΜΙΕΣ] = '" & [ΕΠΩΝΥΜΙΕΣ] & "'"))

Τώρα στην ερώτηση σου δες 2 επιλογές:

1) Με χρήση DSUM()

Private Sub Button1_Click()
    Dim x As Currency
    If Not Me.NewRecord Then
        x = Nz(DSum("[ΤΕΛΙΚΗ ΑΞΙΑ]", "[ΕΓΓΡΑΦΕΣ]", "[ΕΠΩΝΥΜΙΕΣ] = '" & Me.ΕΠΩΝΥΜΙΕΣ & "'"))
        If x = 0 Then
            MsgBox "Δεν έγιναν πωλήσεις."
        Else
            MsgBox "ΣΥΝΟΛΙΚΕΣ ΠΩΛΗΣΕΙΣ: " & FormatNumber(x) & " €.", , "ΠΩΛΗΣΕΙΣ"
        End If
    End If
End Sub

2) Με χρήση Dao.Recordset

Private Sub Button1_Click()
    Dim df As QueryDef
    Dim rs As DAO.Recordset
    Set df = CurrentDb.QueryDefs("sam_ep")
    df![[Forms]![ΕΓΓΡΑΦΕΣ]![ΕΠΩΝΥΜΙΕΣ]] = Me.ΕΠΩΝΥΜΙΕΣ
    Set rs = df.OpenRecordset
    If rs.RecordCount > 0 Then
        MsgBox "ΣΥΝΟΛΙΚΕΣ ΠΩΛΗΣΕΙΣ " & FormatNumber(rs.Fields("ΆθροισμαΤουΤΕΛΙΚΗ ΑΞΙΑ")) & " €.", , "ΠΩΛΗΣΕΙΣ" 
    Else
        MsgBox "Δεν έγιναν πωλήσεις."
    End If
    rs.Close
    Set rs = Nothing
End Sub

Τάσος

[ΤΖΙΜΗΣ]

Taso ευχαριστώ θερμά για τις προτάσεις σου.
Με πολύ εκτίμηση Τζίμης