Forum - Εισαγωγή περιεχομένου αρχείου txt

Forum (https://www.ms-office.gr/forum/)

- Access - Ερωτήσεις / Απαντήσεις (https://www.ms-office.gr/forum/access-erotiseis-apantiseis/)

- - Εισαγωγή περιεχομένου αρχείου txt (https://www.ms-office.gr/forum/access-erotiseis-apantiseis/1420-eisagogi-periexomenoy-arxeioy-txt.html)

sarafis

07-10-11 01:13

Εισαγωγή περιεχομένου αρχείου txt

Καλημέρα σε όλους
Προσπαθώ να εισάγω το περιεχόμενο από αρχεία txt χρησιμοποιώντας
Dim keimeno as String
Dim sFileText As String
Dim iFileNo As Integer
iFileNo = FreeFile
Open "c:\test.txt" For Input As #iFileNo
keimeno = ""
Do While Not EOF(iFileNo)
Input #iFileNo, sFileText
keimeno = keimeno & " " & sFileText
Loop
Debug.Print sFileText
Close #iFileNo
Δουλεύει και με πολλές γραμμές αλλά έχω πρόβλημα με την κωδικοποίηση των χαρακτήρων. Τα αρχεία είναι αποθηκευμένα σε μορφή "unicode big endian" και όπου υπάρχουν ελληνικοί χαρακτήρες εμφανίζονται ιερογλυφικά.
Παρόλο που έψαξα για αρκετές ώρες δεν κατάφερα να βρώ κάτι. Ελπίζω πως κάποιος θα είναι σε θέση να βοηθήσει.

Tasos

07-10-11 09:31

Καλημέρα σε όλους!
Αγαπητέ Στέλιο, δοκίμασε:

Κώδικας:

Option Explicit
 

Sub test()

    Dim MyText As String

    MyText = ReadFromTextFile(TextFileName:="c:\test.txt")

    Debug.Print MyText

End Sub
 

Function ReadFromTextFile(TextFileName As String) As String

    With CreateObject("ADODB.Stream")

        .Open

        .Type = 2    ' Κείμενο

        .Charset = "Unicode"

        .LoadFromFile (TextFileName)

        ReadFromTextFile = .ReadText

        'Η παρακάτω γραμμή κάνει ότι κάνει και η συνάρτηση σου στο σημείο(keimeno = keimeno & " " & sFileText):

        'ReadFromTextFile = Replace(oStream.ReadText, vbNewLine, " ")

        .Close

    End With

End Function

Ελπίζω να σε εξυπηρετεί!

Φιλικά

Τάσος

sarafis

07-10-11 12:53

Τάσο δεν έχω λόγια να σε ευχαριστήσω Δουλεύει άψογα.
Για μια ακόμη φορά με έσωσες. Δραττόμενος της ευκαιρίας θέλω να ευχαριστήσω και όλους τους συμμετέχοντες στο Forum καθώς από τις απαντήσεις τους σε διάφορα προβλήματα έχουν έμεσα δώσει λύσεις και σε δικές μου απορίες.

Tasos

07-10-11 13:19

Νάσαι καλά φίλε μου!

Σ ευχαριστώ για τη συμμετοχή σου και φυσικά για το ήθος σου.

Καλό απόγευμα!

Τάσος

Η ώρα είναι 13:07.

Search Engine Optimization by vBSEO 3.3.2