[ Φόρμες ] Διαφανής Φόρμα

[artchrist73]

ΚΑΛΗΣΠΕΡΑ ΣΕ ΟΛΟΥΣ ΣΑΣ ΔΕΝ ΞΕΡΩ ΠΩΣ ΝΑ ΣΑΣ ΕΥΧΑΡΙΣΤΗΣΩ ΓΙΑ ΤΙΣ ΒΟΗΘΕΙΕΣ ΤΟΥ ΠΑΡΕΛΘΟΝΤΟΣ ΕΙΛΙΚΡΙΝΑ ΜΟΥ ΛΥΣΑΤΕ ΠΟΛΛΕΣ ΑΠΟ ΤΙΣ ΑΠΟΡΙΕΣ ΜΟΥ!!!!
ΠΩΣ ΜΠΟΡΩ ΝΑ ΚΑΝΩ ΔΙΑΦΑΝΗ ΜΙΑ ΦΟΡΜΑ?

[Tasos]

Καλησπέρα Αντώνη!

Για να κάνεις το φόντο μιας φόρμας διαφανές:

• Φρόντισε η φόρμα να έχει την ιδιότητα "Αναδυόμενη" = "Ναι"
• Φρόντισε επίσης να αποκρύψεις τους δείκτες επιλογής εγγραφών, τα κουμπιά μετακίνησης (προαιρετικό).

Στη λειτουργική μονάδα της φόρμας μπορείς χρησιμοποίησε τον παρακάτω κώδικα:

Option Compare Database
Option Explicit
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" ( _
        ByVal hwnd As Long, _
        ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" ( _
        ByVal hwnd As Long, _
        ByVal nIndex As Long, _
        ByVal dwNewLong As Long) As Long

Private Declare Function SetLayeredWindowAttributes Lib "user32" ( _
        ByVal hwnd As Long, _
        ByVal crKey As Long, _
        ByVal bAlpha As Byte, _
        ByVal dwFlags As Long) As Long
        
Private Const GWL_EXSTYLE =  -20&
Private Const WS_EX_LAYERED = &H80000
Private Const LWA_COLORKEY = &H1

Private Sub Form_Load()
    SetWindowLong Me.hwnd, GWL_EXSTYLE, GetWindowLong(Me.hwnd, GWL_EXSTYLE) Or WS_EX_LAYERED
    SetLayeredWindowAttributes Me.hwnd, vbCyan, 0&, LWA_COLORKEY
    Me.Section(0).BackColor = vbCyan
End Sub

Καλή συνέχεια!

Φιλικά

Τάσος

[artchrist73]

ποπό υπέροχα ευχάριστο!!!!!!!!!!!

[artchrist73]

Και αν θέλουμε να δείχνει θαμπά με κάποιο χρώμα την forma προσθέτουμε κώδικα vba?

[Tasos]

Καλημέρα σε όλους!
Αντώνη δοκίμασε:

Private Declare Function GetWindowLong Lib "user32" Alias _
              "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias _
             "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, _
                                                         ByVal dwNewLong As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" _
              (ByVal hwnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, _
                                                     ByVal dwFlags As Long) As Long

Private Const GWL_EXSTYLE = (-20)
Private Const WS_EX_LAYERED = &H80000
Private Const LWA_ALPHA = &H2&

Private Sub Form_Load()
    SetWindowLong Me.hwnd, GWL_EXSTYLE, GetWindowLong(Me.hwnd, GWL_EXSTYLE) Or WS_EX_LAYERED
    SetLayeredWindowAttributes Me.hwnd, 0, CByte(200), LWA_ALPHA 
    ' CByte(200) όπου 200 = ο συντελεστής διαφάνειας της φόρμας (1 - 255)
End Sub

Καλή συνέχεια!

Τάσος

[artchrist73]

ευχαριστω πολύ !!!

Παιδιά δεν μας ανεβάζεται ένα συνημμένο να δούμε και εμείς πως είναι αυτό που φτιάξατε;;;;;Σας ευχαριστώ

[ΠΕΤΡΟΣ]

Ευχαριστώ πολύ ήταν κάτι που το έψαχνα χρόνια