[Tasos]

Καλησπέρα Χρήστο!

Τέλος καλό όλα καλά!

Προς πληροφόρηση τα κόκκινα γράμματα δεν είναι τόσο ευανάγνωστα όσο τα μαύρα.

Στο θέμα μας λοιπόν.

Κάνε τα εξής:

1) Άνοιξε τον VBE (ALT+F11) και άλλαξε το όνομα Φύλλο3 σε Sheet2 (βλ. εικόνα).



2) Kάνε διπλό κλικ στο ThisWorkbook και στο παράθυρο δεξιά πέρασε τον παρακάτω κώδικα:

Private Sub Workbook_BeforePrint(Cancel As Boolean)
    Dim strDate As String, i As Integer, rng As Range, c As Range
    If ActiveSheet.CodeName = "Sheet2" Then 'Sheet2 = το κωδικό όνομα του φύλλου "ΠΙΝΑΚΙΟ".
        strDate = "Δικάσιμος της ......"
        If Sheet2.AutoFilterMode Then
                    If Sheet2.AutoFilter.Range.Columns(1).SpecialCells(xlCellTypeVisible).Count > 1 Then
                Set rng = Sheet2.AutoFilter.Range
                For i = 1 To rng.Columns.Count
                    If rng.Columns(i).Column = 6 Then
                        If Sheet2.AutoFilter.Filters(i).On Then
                            Set rng = rng.Columns(i)
                            For Each c In rng.SpecialCells(xlCellTypeVisible)
                            If IsDate(c) Then
                            Exit For
                            End If
                            Next
                            If IsDate(c) Then
                                strDate = "Δικάσιμος της " & Format(c, "dd/mm/yyyy")
                            End If
                        End If
                        Exit For
                    End If
                Next
            End If
        End If
    With Sheet2.PageSetup
        .CenterHeader = strDate
       ' .CenterFooter = strDate 
    End With
    End If
End Sub

3) Αν έχεις περάσει κάποιο τύπο στο κελί F1 μπορείς να τον αφαιρέσεις.

4) Φρόντισε στη διαμόρφωση της σελίδας να αλλάξεις το μέγεθος της γραμματοσειράς στην αριστερή κεφαλίδα τόσο ώστε να μην καλύπτει τη μεσαία κεφαλίδα που θα περιέχει την ημερομηνία από το φίλτρο.

5) Αποθήκευσε και δοκίμασε

Σε Excel μέχρι και την έκδοση 2007 μπορεί να δει κανείς τα αποτελέσματα στην προεπισκόπηση εκτύπωσης χωρίς να χρειαστεί να εκτυπώσει.

.

Καλή συνέχεια!

Φιλικά

Τάσος