[Tasos]

Καλησπέρα Δημήτρη!

Πριν δοκιμάσεις τα παρακάτω άλλαξε την ιδιότητα της φόρμας "Αναδυόμενη" σε "Ναι".

Στη φόρμα πέρασε το παρακάτω:

Option Compare Database
Option Explicit

Private Sub Form_Load()
    ShowReport
End Sub

Private Sub ShowReport()
    Dim stDocName As String
    On Error GoTo Err_ShowReport
    stDocName = "rpt1"
    DoCmd.Minimize 'Ελαχιστοποίηση της φόρμας
    Me.Move 20, 20, Me.WindowWidth, Me.WindowHeight 'Μετακίνησητης φόρμας πάνω αριστερά
    
    DoCmd.OpenReport stDocName, acViewPreview, , , , Me.Name
    ' ή "Το_όνομα_της_κύριας_φόρμας" αν ο κώδικας τρέχει σε λειτουργική μονάδα υποφόρμας
        
    DoCmd.RunCommand acCmdFitToWindow 'Προσαρμογή του περιεχόμενου της έκθεσης στην οθόνη
Exit_ShowReport:
    Exit Sub

Err_ShowReport:
    MsgBox Err.Description
    Resume Exit_ShowReport

End Sub

Και στην έκθεση:

Option Compare Database
Option Explicit

Private Sub Report_Open(Cancel As Integer)
' Me.OpenArgs = το όνομα της φόρμας προς επαναφορά από την ελαχιστοποίηση
    If Nz(Me.OpenArgs) <> 0 Then DoCmd.Maximize
End Sub

Private Sub Report_Close()
    If Nz(Me.OpenArgs) <> 0 Then
        If SysCmd(10, 2, Me.OpenArgs) Then
            DoCmd.SelectObject acForm, Me.OpenArgs
            DoCmd.Restore
        End If
    End If
End Sub

Φιλικά

Τάσος