[kapetang]

Καλημέρα

Στο συνημμένο η συνάρτηση υπολογισμού του φόρου διαμορφώθηκε ως εξής:

Function FMY_annual(Yposo, Optional children As Long = 0) As Double
'Υπολογίζει τον ετήσιο φόρο (Ν. 4387/2016)
'Yposo είναι το ετήσιο καθαρό ειασόδημα
'-------------------------------------------------------

    Dim foros As Double, meiosi As Double, arrM As Variant

    'Ετήσιος φόρος με βάση τα κλιμάκια
    Select Case Yposo
    Case Is <= 10000
        foros = Round(Yposo * 9 / 100, 2)
    Case Is <= 20000
        foros = 900 + Round((Yposo - 10000) * 22 / 100, 2)
    Case Is <= 30000
        foros = 3100 + Round((Yposo - 20000) * 28 / 100, 2)
    Case Is <= 40000
        foros = 5900 + Round((Yposo - 30000) * 36 / 100, 2)
    Case Else
        foros = 9500 + Round((Yposo - 40000) * 44 / 100, 2) '<- άλλαξα το 45 σε 44
    End Select

    'Μείωση ετήσιου φόρου λόγω εξαρτώμενων τέκνων
    arrM = Array(777, 810, 900, 1120, 1340)
    If children <= 4 Then
        meiosi = arrM(children)
    Else
        meiosi = 1340 + (children - 4) * 220
    End If
    If children = 0 Then
        meiosi = -meiosi * (Yposo <= 20000)    '<- μόνο για εισόδημα <=20000
    End If
    If foros > meiosi Then
        FMY_annual = Round((foros - meiosi) * 0.985, 2) '<-Μείωση 1,5% ισχύει;
    Else
        FMY_annual = 0
    End If

End Function

Εδώ πρέπει να τονίσω ότι:

1) Η μείωση, για 0 τέκνα, των 777 € ισχύει μόνο αν το εισόδημα δεν υπερβαίνει τα 20.000 €

2) Γίνεται μείωση του φόρου κατά 1,5%.

Αν κάτι από τα παραπάνω δεν ισχύει θα πρέπει να το αλλάξεις.

Στις υπόλοιπες συναρτήσεις (πχ εισφορά αλληλεγγύης) δεν έγιναν αλλαγές.

Συνεπώς, αν κάτι άλλαξε στη σχετική νομοθεσία υπολογισμού, θα πρέπει να γίνουν οι κατάλληλες προσαρμογές.