[Tasos]

Καλησπέρα σε όλους!


Μάριε, Ο Κωνσταντίνος ήδη σου έδωσε τη σωστή απάντηση στην ερώτηση αλλά εκτός από το
συμβάν "docurl_Click()", θα σου χρησιμεύσουν και τα συμβάντα του ίδιου του Στοιχείου Ελέγχου.
Έχε υπόψη σου ότι το Στοιχείο Ελέγχου παρέχεται ώς έχει και δεν υποστηρίζεται επίσημα.

Στο παρελθόν είχα φτιάξει κάτι παρόμοιο.
Παραθέτω μέρος του κώδικα που ίσως να σου φανεί χρήσιμο.

Option Compare Database
Option Explicit

Private WithEvents oFrame As DSOFramer.FramerControl

Private Sub Form_Load()
    Set oFrame = Me.Framer.Object
    oFrame.BorderStyle = dsoBorder3D
End Sub

Private Sub oFrame_OnDocumentOpened(ByVal File As String, ByVal Document As Object)
    oFrame.MenuBar = True
    oFrame.Toolbars = True
    If Right(Document.FullName, 4) Like "*doc*" Then
        With Document.Application
            .ScreenUpdating = False
            .ActiveWindow.View.Zoom.PageFit = 2
            If .ActiveWindow.View.Zoom.Percentage > 100 Then
                .ActiveWindow.View.Zoom.Percentage = 100
                .ActiveWindow.View.Zoom.PageFit = 0
            End If
            .ScreenUpdating = True
        End With
    End If
End Sub

Private Sub oFrame_BeforeDocumentClosed(ByVal Document As Object, Cancel As Boolean)
    Dim vbPrompt As VbMsgBoxResult
    On Error Resume Next
    If oFrame.IsDirty Then
        vbPrompt = MsgBox("Would you like to save the file before closing it?", _
        vbQuestion Or vbYesNoCancel, "Save Changes?")
        If vbPrompt = vbCancel Then
            Cancel = True
        ElseIf vbPrompt = vbYes Then
            If oFrame.IsReadOnly Or _
                    Len(oFrame.DocumentFullName) = 0 Then
                oFrame.ShowDialog dsoDialogSave
            Else
                oFrame.Save
            End If
        End If
    End If
End Sub


Private Sub  docurl_Click()
    If oFrame Is Nothing Then Set oFrame = Me.Framer.Object
    oFrame.Close
    oFrame.Open docurl 
End Sub


Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
        oFrame.Close
    	  Set oFrame = Nothing
    'DoCmd.Quit
End Sub

Φιλικά

Τάσος