[Tasos]

Καλημέρα σε όλους!

Δημήτρη, στη βάση που ανέβασες, έχεις βάλει αρκετούς περιορισμούς κάτι που δεν διευκολύνει τόσο τα μέλη του φόρουμ, όσο και για σένα τον ίδιο αφού ακόμα σχεδιάζεις τη βάση.

Εκτός αυτού, πριν επισυνάψεις το αρχείο κάνε μια συμπύκνωση & επιδιόρθωση. Ο όγκος του αρχείου θα μειωθεί σημαντικά με αυτόν τον τρόπο.

Τώρα στη ερώτηση σου:

Φρόντισε να επαναφέρεις τη βάση στην αρχική μορφή της (Άρση περιορισμών) για να μπορείς να κάνεις τις δοκιμές σου.

Στην ιδιότητα Ετικέτα του πεδίου Επώνυμο πληκτρολόγησε τον αριθμό 2 (υποδηλώνει τη σειρά εμφάνισης του πεδίου φόρμας (Επώνυμο ή Surname) στο Word.

Στην ιδιότητα Ετικέτα του πεδίου Κείμενο8*** πληκτρολόγησε τον αριθμό 1 (υποδηλώνει τη σειρά εμφάνισης του πεδίου φόρμας (Όνομα ή Name) στο Word.

Κάνε το ίδιο και στα υπόλοιπα πεδία της Access.

Άλλαξε το όνομα στο κουμπί "Υπεύθυνη δήλωση" σε CmdSendToWD
κατόπιν αντιστοίχησε τον παρακάτω κώδικα στο συμβάν "Με το κλικ" του κουμπιού:

Private Sub CmdSendToWD_Click()
    Dim wdDoc As Object, wdPath As String, Ctl As Access.Control
    ' wdPath = "C:\Δηλώσεις\Υπεύθυνη δήλωση.doc"  'Προσάρμοσε τη διαδρομή
    wdPath = CurrentProject.Path & "\Υπεύθυνη δήλωση.doc"   'Για να τρέξει το παράδειγμα σου
    If Dir(wdPath, vbDirectory) <> vbNullString Then
        Set wdDoc = GetObject(wdPath)
    Else
        MsgBox "Το αρχείο δεν βρέθηκε!"
        Exit Sub
    End If
    For Each Ctl In Me.Section(0).Controls
        If TypeOf Ctl Is Access.TextBox Then
            If IsNumeric(Ctl.Tag) Then
                wdDoc.FormFields(CInt(Ctl.Tag)).result = Nz(Ctl, vbNullString)
            End If
        End If
    Next
    wdDoc.Application.Visible = True
    AppActivate wdDoc.Name
End Sub

Επίσης, φρόντισε να κλειδώσεις το έγγραφο Word .
Πως;

Κάνε κλικ στην επιλογή Εργαλεία >Προστασία εγγράφου...

Τσέκαρε το "Δυνατότητα μόνο αυτού του τύπου επεξεργασίας στο έγγραφο:"
και από τη λίστα ακριβώς από κάτω επίλεξε: Συμπλήρωση φορμών.

Πάτησε το κουμπί "Ναι να ξεκινήσει η ενεργοποίηση προστασίας"

Καλή συνέχεια!

Τάσος

*** Το Όνομα. Η ονοματολογία που χρησιμοποιείς θα σε κουράσει και μπορεί να προκαλέσει λάθη.