Forum - VBA Όριο γραμμων σε TextBox

Forum (https://www.ms-office.gr/forum/)

- Excel - Ερωτήσεις / Απαντήσεις (https://www.ms-office.gr/forum/excel-erotiseis-apantiseis/)

- - [VBA] Όριο γραμμων σε TextBox (https://www.ms-office.gr/forum/excel-erotiseis-apantiseis/5166-orio-grammon-se-textbox.html)

Όριο γραμμων σε TextBox

Καλημέρα,
Σε μια textbox με scrollbarsvertical θέλω να ελέγχω το πλήθος των γραμμών
της textbox Π.χ. μόλις συμπληρωθούν 5 γραμμές να μη σου επιτρέπει να γράφεις άλλο!

Ευχαριστώ για όποια βοήθεια

Καλησπέρα Γιώργο,

Αφού θέσεις τις ιδιότητες MultiLine=True και EnterKeyBehavior=True του textbox, στο γεγονός του KeyDown δοκίμασε το εξής:

Κώδικας:

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)

    If TextBox1.LineCount >= 5 And KeyCode = 13 Then KeyCode = 0

End Sub

Καλησπέρα Χρήστο,
Σε' Ευχαριστώ για την άμεση απάντηση,
δεν ξέρω που κάνω λάθος και δεν δουλεύει,
ανεβάζω συνημμένο

Γιώργο,

Το textbox έχει μια ιδιότητα (EnterKeyBehavior), η οποία αν είναι True δίνει τη δυνατότητα στο κουμπί Enter να δημιουργεί νέα γραμμή, όπως στους κειμενογράφους.

Απλά δεν την είχες θέσει σε True. Δοκίμασε το συνημμένο να δεις αν λειτουργεί τώρα.

Καλησπέρα
Χρήστο, επειδή κάποιοι χρήστες μπορεί να «ξεχάσουν» τις ιδιότητες που απαιτούνται,
γράψε ό, τι χρειάζεται στο Initialize της φόρμας, και όλα καλά.

Δείτε και μια ακόμα λύση, στο Change του TextBox.

Κώδικας:

Option Explicit

Const Rlimit As Byte = 5 'Καταχωρήστε το όριο γραμμών, ΕΔΩ

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
 Private Sub UserForm_Initialize()

    With Me.TextBox1

        .MultiLine = True

        .ScrollBars = fmScrollBarsVertical

        .EnterKeyBehavior = True
     End With

End Sub

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
 Private Sub TextBox1_Change()
 Dim temp As String

    With Me.TextBox1

        If .CurLine > Rlimit - 1 Then

            MsgBox "Δεν Επιτρέπονται, Περισσότερες Από: " & Rlimit  & " Γραμμές."

            temp = .Text

                If Right(temp, 2) = vbCrLf Then

                    temp = Left(temp, Len(temp) - 2)

                Else

                    temp = Left(temp, Len(temp) - 1)

                End If

            .Text = temp

        End If

        'Προαιρετικά

        .Value = Application.WorksheetFunction.Proper(TextBox1.Value)
     End With

End Sub

Η τελευταία γραμμή ('Προαιρετικά)
εμφανίζει το κείμενο με πρώτο γραμμα κάθε λέξης κεφαλαίο.

Σπύρο,

Ναι, όντως έχεις δίκιο! Καλύτερα με τη φόρτωση της φόρμας να τροποποιούνται οι απαιτούμενες ιδιότητες των ελεγκτηρίων.

Γιώργο,

Μια μικρή παραλλαγή του προηγούμενου αρχείου. Κάθε φορά που φορτώνεται η φόρμα, οι 3 ιδιότητες του textbox που χρειάζεσαι αρχικοποιούνται σύμφωνα με τις ανάγκες σου.

Χρήστο δοκίμασα το συνημμένο που ανέβασες, και πάλι,
μετά το όριο των 5 γραμμών σου επιτρέπει να γράφεις απεριόριστες γραμμές.

Γιώργο,

Τότε χρειάζεσαι τον κώδικα του Σπύρου.

Ο δικός μου κώδικας θεωρεί τη νέα γραμμή κάθε φορά που πατάς Enter.

Καλημέρα,
Χρήστο όπως το λες η πρόταση του Σπύρου είναι αυτή ακριβώς που θέλω.
Σας Υπέρ Ευχαριστώ και εσένα και το Σπύρο.

Να’ είστε καλά,
Καλή συνέχεια.

Για να αποδώσουμε τα του Καίσαρος τω Καίσαρι,
να πούμε ότι η λύση του Χρήστου, είναι καλή και δουλεύει αν...

Εξήγηση:
Η λύση με το συμβάν Change που έδωσα,
είναι μια άλλου είδους λύση που θα μπορούσε κανείς να χρησιμοποιήσει.

Όμως, αν για κάποιο λόγο, δεν μπορούμε να χρησιμοποιήσουμε το Change, τί θα γίνει;

Το σφάλμα με την συνέχεια των γραμμών στον κώδικα του Χρήστου,
εμφανίζεται αν, αντί Enter, χρησιμοποιήσει κανείς το Tab πλήκτρο.

Αν όμως βάλουμε στο Initialize και

Κώδικας:

.TabKeyBehavior = False

τότε θα λειτουργήσει μια χαρά.

Ακόμα θα μπορούσε κανείς να αλλάζει γραμμές με Shift + Enter
και να μην έχει στο Initialize, καμία ιδιότητα, αν βάλει στο KeyDown:

Κώδικας:

If TextBox1.LineCount >= 5 And KeyCode = 13 Or KeyCode = 9 Then KeyCode = 0

Όλα αυτά είναι θεωρίες και εναλλακτικές, για να χρησιμοποιήσει κανείς
και να αποφασίσει τι τελικά θα κάνει, αν βέβαια γνωρίζει και τον υπόλοιπο κώδικα της φόρμας,
την συμπεριφορά και χρήση του TextBox, του τι θέλει ο χρήστης, αν τον βολεύει πληκτρολόγιο ή ποντίκι...κ.ά
πράγματα που δεν γνωρίζουμε.

Καλησπέρα,
Σε’ Ευχαριστώ Σπύρο για άλλη μια φορά για όλες αυτές τις εναλλακτικές λύσεις,
Έχεις το χάρισμα να μεταδίδεις τη γνώση με πολύ απλή και κατανοητή περιγραφή.

Σε’ Ευχαριστώ πολύ.
Να’ σαι καλά.

Με εκτίμηση Γιώργος

Καλή συνέχεια Γιώργο, ευχαριστώ για τα καλά λόγια.