Διαδρομή αρχείου αποθήκευσης
 

Καλησπέρα στην καταπληκτική κοινότητα, Στο παράδειγμα που επισυνάπτω με την μακροεντολή εκτελώ εξαγωγή με μορφοποίηση σε συγκεκριμένο φάκελο πχ C:\Users\USER\OneDrive\Υπολογιστής\ΑΠ ΟΘΗΚΕΥΜΕΝΗ ΕΞΑΓΩΓΗ\ΑΡΧΕΙΟ\b1.pdf
Το ζητούμενο είναι να επιλέγω το όνομα αποθήκευσης κάθε φορά και δεύτερο μετά την αποθήκευση να μου ανοίγει ο φάκελος αποθήκευσης.
Ευχαριστώ εκ των προτερων
Με εκτίμηση

Γιώργος

Καλημέρα. Για δες αν αυτό σε καλύπτει.
Ανοιγεις την βαση σου πατας Alt+G και θα δεις εχω ενα Module.
Το καλείς στο Immediate Window σαν ?SaveAsPDFAndOpenFolder

Χρήστο ευχαριστώ πολύ, ανοίγει το φάκελο αποθήκευσης πλην όμως δεν αποθηκεύει στη διαδρομή που έχω επιλέξει με τη μακροεντολή αλλά αποθηκεύει στον φάκελο που είναι η βάση δεδομένων. Κάνω κάτι λάθος ;
και πάλι ευχαριστώ

Δεν έγραψες διαδρομή. Έγραψες όνομα αποθήκευσης αν δεν κανω λαθος. Αυτό που σου έστειλα αποθηκεύει το αρχείο σου στον φάκελο που είναι η εφαρμογή σου.

έχεις δίκιο

Function SaveAsPDFAndOpenFolder()
On Error GoTo SaveAsPDFAndOpenFolder_Err

Dim savePath As String
Dim reportName As String

' Prompt the user to enter a name for the PDF file
reportName = InputBox("Enter a name for the PDF file (without extension):")

' Check if the user canceled the input
If Len(reportName) = 0 Then
Exit Function
End If

' Append ".pdf" extension to the file name
reportName = reportName & ".pdf"

' Get a folder path from the user
With Application.FileDialog(4) ' msoFileDialogFolderPicker
.Title = "Select a Folder"
.Show
If .SelectedItems.Count > 0 Then
savePath = .SelectedItems(1) & "\" & reportName
Else
' User cancelled the folder picker
Exit Function
End If
End With

' Open the report in Print Preview mode
DoCmd.OpenReport "Πίνακας1", acViewPreview, , , acHidden

' Save the report as PDF
DoCmd.OutputTo acOutputReport, "Πίνακας1", acFormatPDF, savePath

' Close the report
DoCmd.Close acReport, "Πίνακας1"

' Open the folder where the PDF file is saved
Shell "explorer.exe /select," & savePath, vbNormalFocus

SaveAsPDFAndOpenFolder_Exit:
Exit Function

SaveAsPDFAndOpenFolder_Err:
MsgBox Err.Description, vbCritical
Resume SaveAsPDFAndOpenFolder_Exit
End Function

Αντικατέστησε τον κώδικα με αυτόν

σε ευχαριστώ πολύ Χρήστο, νάσε πάντα καλά.

Έγινε η δουλειά σου?