Ανανέωση ιστοσελίδας

[Ms-Office-Development Team]

´, ¡, ¢, ¸, ¹, º, ¼, ¾, ¿, À, Á, Â, Ã, Ä, Å, Æ, Ç, È, É, Ê, Ë, Ì, Í, Î, Ï, Ð, Ñ, Ó, Ô, Õ, Ö, ×, Ø, Ù, Ú, Û, Ü, Ý, Þ, ß, à, á, â, ã, ä, å, æ, ç, è, é, ê, ë, ì, í, î, ï, ð, ñ, ò, ó, ô, õ, ö, ÷, ø, ù, ú, û, ü, ý, þ

Πολλοί από μας έχουν συναντήσει τους παραπάνω χαρακτήρες.
Σε παλαιότερες εκδόσεις Word, υπήρχε σχετική (και πολύ χρήσιμη) εντολή στο μενού Εργαλεία > Επιδιόρθωση κατεστραμμένου κείμενου.. που μας επανέφερε τους χαρακτήρες αυτούς στην αρχική τους μορφή δηλ.:

΄, ΅, Ά, Έ, Ή, Ί, Ό, Ύ, Ώ, ΐ, Α, Β, Γ, Δ, Ε, Ζ, Η, Θ, Ι, Κ, Λ, Μ, Ν, Ξ, Ο, Π, Ρ, Σ, Τ, Υ, Φ, Χ, Ψ, Ω, Ϊ, Ϋ, ά, έ, ή, ί, ΰ, α, β, γ, δ, ε, ζ, η, θ, ι, κ, λ, μ, ν, ξ, ο, π, ρ, ς, σ, τ, υ, φ, χ, ψ, ω, ϊ, ϋ, ό, ύ, ώ.

Δυστυχώς, για την έκδοση του 2007 δεν υποστηρίζεται πια κάτι ανάλογο επειδή η Microsoft λόγω της σπανιότητας της χρήσης του θεώρησε ότι πρέπει να αφαιρεθεί από το τότε νέο της πακέτο.
Ταυτόχρονα πρόσφερε και προσφέρει μέχρι σήμερα κάποιο Addin για όσους ενδιαφέρονται αλλά, το Addin αυτό προϋποθέτει Word 2000 (!!) για να εγκατασταθεί.

Εναλλακτική λύση λοιπόν στο πρόβλημα αναλαμβάνει ηVBA με τη χρήση του παρακάτω κώδικα:

Option Explicit



Sub FixBrokenText()

    Dim arr1 As Variant, arr2 As Variant, i As Integer

    arr1 = Array(180, 161, 162)

    arr2 = Array(900, 901, 902)

    With ActiveDocument.Range.Find

        .Format = False

        .MatchCase = True

        .MatchWholeWord = False

        .MatchWildcards = False

        .MatchSoundsLike = False

        .MatchAllWordForms = False

        For i = 184 To 254

            .Text = ChrW(i)

            .Replacement.Text = ChrW(i + 720)

            .Execute Replace:=wdReplaceAll

        Next

        For i = 0 To UBound(arr1)

            .Text = ChrW(arr1(i))

            .Replacement.Text = ChrW(arr2(i))

            .Execute Replace:=wdReplaceAll

        Next

    End With

End Sub
 
 
 

Ms-Office-Team (Τάσος)