Ανανέωση ιστοσελίδας

[Giorgos]

Καλησπερα σε ολους

Εχουμε κανενα γρηγορο κωδικα να εντοπιζω πια φορμα ειναι ανοιχτή..??

Γιώργος

[Tasos]

Καλησπέρα σε όλους!

Φίλε μου Γιώργο o παρακάτω κώδικας ελέγχει αν μια φόρμα είναι ανοιχτή
σε κανονική προβολή:

Option Compare Database
Option Explicit

Function IsOpen(MyFormName$) As Boolean
    If SysCmd(10, 2, MyFormName) <> 0 Then
        If Forms(MyFormName).CurrentView = 1 Then IsOpen = True
    End If
End Function

Sub test()
    If IsOpen("MyFormName") Then MsgBox "Form is running!"
End Sub

Τα λέμε...

Τάσος

[Giorgos]

Καλημέρα Τασο

Σε ευχαριστώ πολύ..!

Γιωργος

[Giorgos]

Τασο Δεν του αρεσει το Isopen.. Γιατί?

[Tasos]

Το MyFormName.... μου ξέφυγε!!

[Giorgos]

Τασο πρεπει να του λειπει βιβλιοθηκη μαλλον γι αυτο ισος δεν του αρεσει...! δεν το βρισκω στον κωδικα καθολου..

[Giorgos]

για το isOpen λεω..

[Tasos]

Δες ένα παράδειγμα στο συνημμένο.

Τάσος

[Giorgos]

Ok..! Τασο.. το ειχα περασει μπακαλιστικα..!!

[nisgia]

Καλησπέρα στη παρέα!

Ορίστε μερικές γρήγορες και σχετικές συναρτησούλες κι από μένα:

Function LastForm() As String
    'Το όνομα της τελευταίας φόρμας που άνοιξε.
    On Error Resume Next
    LastForm = Forms(Forms.Count - 1).Name
End Function

Function FirstForm() As String
    'Το όνομα της πρώτης φόρμας που άνοιξε.
    On Error Resume Next
    FirstForm = Forms(0).Name
End Function

Function IsOpenForm(ByVal strFormName As String) As Boolean
    'Έλεγχος αν μια φόρμα με όνομα strFormName  είναι ανοιχτή.
    On Error Resume Next
    IsOpenForm = Len(Forms(strFormName).Name) > 0
End Function

Function FormCurrView(ByVal strFormName As String) As AcCurrentView
    'Η προβολή μιας ανοιχτής φόρμας με όνομα strFormName.
    On Error Resume Next
    FormCurrView = Forms(strFormName).CurrentView
End Function

Function FormHWnd(ByVal strFormName As String) As Long
    'Ο χειριστής παραθύρου μιας ανοιχτής φόρμας με όνομα strFormName.
    On Error Resume Next
    FormHWnd = Forms(strFormName).Hwnd
End Function

Και ένα παράδειγμα χρήσης τους...

Sub Test()
    Dim strMsg As String
    Select Case FormCurrView(LastForm)
        Case acCurViewFormBrowse
            strMsg = " form view."
        Case acCurViewDatasheet
            strMsg = " datasheet view."
        Case acCurViewPivotChart
            strMsg = " pivot chart view."
        Case acCurViewPivotTable
            strMsg = " pivot table view."
        Case Else
    End Select
    
    If Len(strMsg) Then
        MsgBox LastForm & " is open in " & strMsg, vbInformation
    Else
        MsgBox "There are no open forms!", vbExclamation
    End If
End Sub

Ελπίζω να σας φανούν χρήσιμες.
Γιάννης