Ανανέωση ιστοσελίδας

[sarafis]

Καλημέρα σε όλους
Προσπαθώ να εισάγω το περιεχόμενο από αρχεία txt χρησιμοποιώντας
Dim keimeno as String
Dim sFileText As String
Dim iFileNo As Integer
iFileNo = FreeFile
Open "c:\test.txt" For Input As #iFileNo
keimeno = ""
Do While Not EOF(iFileNo)
Input #iFileNo, sFileText
keimeno = keimeno & " " & sFileText
Loop
Debug.Print sFileText
Close #iFileNo
Δουλεύει και με πολλές γραμμές αλλά έχω πρόβλημα με την κωδικοποίηση των χαρακτήρων. Τα αρχεία είναι αποθηκευμένα σε μορφή "unicode big endian" και όπου υπάρχουν ελληνικοί χαρακτήρες εμφανίζονται ιερογλυφικά.
Παρόλο που έψαξα για αρκετές ώρες δεν κατάφερα να βρώ κάτι. Ελπίζω πως κάποιος θα είναι σε θέση να βοηθήσει.

[Tasos]

Καλημέρα σε όλους!
Αγαπητέ Στέλιο, δοκίμασε:

Option Explicit

Sub test()
    Dim MyText As String
    MyText = ReadFromTextFile(TextFileName:="c:\test.txt")
    Debug.Print MyText
End Sub

Function ReadFromTextFile(TextFileName As String) As String
    With CreateObject("ADODB.Stream")
        .Open
        .Type = 2    ' Κείμενο
        .Charset = "Unicode"
        .LoadFromFile (TextFileName)
        ReadFromTextFile = .ReadText
        'Η παρακάτω γραμμή κάνει ότι κάνει και η συνάρτηση σου στο σημείο(keimeno = keimeno & " " & sFileText):
        'ReadFromTextFile = Replace(oStream.ReadText, vbNewLine, " ")
        .Close
    End With
End Function

Ελπίζω να σε εξυπηρετεί!

Φιλικά

Τάσος

[sarafis]

Τάσο δεν έχω λόγια να σε ευχαριστήσω Δουλεύει άψογα.
Για μια ακόμη φορά με έσωσες. Δραττόμενος της ευκαιρίας θέλω να ευχαριστήσω και όλους τους συμμετέχοντες στο Forum καθώς από τις απαντήσεις τους σε διάφορα προβλήματα έχουν έμεσα δώσει λύσεις και σε δικές μου απορίες.

[Tasos]

Νάσαι καλά φίλε μου!

Σ ευχαριστώ για τη συμμετοχή σου και φυσικά για το ήθος σου.

Καλό απόγευμα!

Τάσος