[Tasos]

Αγαπητέ μου φίλε Νίκο Καλημέρα!
Σου παραθέτω κάποια παραδείγματα παρακάτω:

Ο κώδικας που να συνδέει την εφαρμογή σου με υπάρχον αρχείο *.xls

Sub LinkToExcelSheet()
    ConnectToExcelSpreadSheet "AccessTablename", "C:\Book1.xls", "Sheet2", "A1:K50"
End Sub

Function ConnectToExcelSpreadSheet(AccTableName$, WBPath$, SheetName$, CellAddress$)
    DoCmd.TransferSpreadsheet _
            TransferType:=acLink, _
            SpreadSheetType:=acSpreadsheetTypeExcel9, _
            TableName:=AccTableName, _
            FileName:=WBPath, _
            HasFieldNames:=True, _
            Range:=SheetName & "!" & CellAddress
End Function

Ο κώδικας που μεταφέρει στο κελί G5 μια τιμή

Sub ExportValueToExcelCell()
    WriteBalueToXLCell "C:\Book2.xls", "Sheet1", "G5", "MyValue"
End Sub

Function WriteBalueToXLCell(WBPath$, SheetName$, CellAddress$, CellValue)
    Dim XL As Object, WB As Object, wks As String
    On Error GoTo ExitHere
    Set XL = CreateObject("Excel.Application")
    'XL.Visible = True
    Set WB = XL.Workbooks.Open(WBPath)
    WB.Sheets(SheetName).Range(CellAddress).Value = CellValue
    WB.Save
ExitHere:
    If Err <> 0 Then MsgBox Err & vbLf & Err.Description
    If Not XL Is Nothing Then
        XL.Quit
        Set XL = Nothing
    End If
End Function

Για να μεταφέρεις (Αποκοπή - Επικόλληση) ένα αρχείο από Path1 σε Path2,
αρκεί να το μετονομάσεις μέσω VBA δηλαδή:

Function RenameFile(SourcePath$, TargetPath$)
    Name SourcePath As TargetPath
End Function

Καλή συνέχεια!

Τάσος